FileReadDouble

double  FileReadDouble(
   int  file_handle,       // handle файла
   int  size=DOUBLE_VALUE  // кол-во байт
   );

//+------------------------------------------------------------------+
//|                                          Demo_FileReadDouble.mq4 |
//|                        Copyright 2014, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property strict
#property indicator_chart_window
#property indicator_buffers 1
//---- plot Label1
#property indicator_label1  "MA"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrGreen
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
#property indicator_separate_window
//--- параметры для чтения данных
input string InpFileName="MA.bin";    // Имя файла
input string InpDirectoryName="Data"; // Имя каталога
//--- глобальные переменные
int      ind=0;
int      size=0;
double   ma_buff[];
datetime time_buff[];
//--- indicator buffer
double   buff[];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- откроем файл
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для чтения",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- сначала прочитаем сколько всего в файле данных
      size=(int)FileReadDouble(file_handle,DOUBLE_VALUE);
      //--- выделим память для массивов
      ArrayResize(ma_buff,size);
      ArrayResize(time_buff,size);
      //--- прочитаем данные из файла
      for(int i=0;i<size;i++)
        {
         time_buff[i]=(datetime)FileReadDouble(file_handle,DOUBLE_VALUE);
         ma_buff[i]=FileReadDouble(file_handle,DOUBLE_VALUE);
        }
      //--- закроем файл
      FileClose(file_handle);
      PrintFormat("Данные прочитаны, файл %s закрыт",InpFileName);
     }
   else
     {
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
      return(INIT_FAILED);
     }
//--- привязка массива к индикаторному буферу с индексом 0
   SetIndexBuffer(0,buff,INDICATOR_DATA);
//--- установка значений индикатора, которые не будут видимы на графике
   SetIndexEmptyValue(0,0.0);
//--- установка направления индексации как в таймсериях
   ArraySetAsSeries(time_buff,true);
   ArraySetAsSeries(ma_buff,true);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   ArraySetAsSeries(time,true);
//--- цикл для еще необработанных баров
   for(int i=prev_calculated;i<rates_total;i++)
     {
      //--- по умолчанию 0
      buff[i]=0;
      for(int j=0;j<size;j++)
        {
         //--- если даты совпадают, то используем значение из файла
         if(time[i]==time_buff[j])
           {
            buff[i]=ma_buff[j];
           }
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }