FileWriteLong

uint  FileWriteLong(
   int   file_handle,     // handle файла
   long  value            // записываемое значение
   );

//+------------------------------------------------------------------+
//|                                           Demo_FileWriteLong.mq5 |
//|                        Copyright 2013, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2013, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- параметры для получения данных из терминала
input string          InpSymbolName="EURUSD";           // валютная пара
input ENUM_TIMEFRAMES InpSymbolPeriod=PERIOD_H1;        // таймфрейм
input datetime        InpDateStart=D'2013.01.01 00:00'; // дата начала копирования данных
//--- параметры для записи данных в файл
input string          InpFileName="Volume.bin"; // имя файла
input string          InpDirectoryName="Data";  // имя директории
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   datetime date_finish=TimeCurrent();
   long     volume_buff[];
   datetime time_buff[];
   int      size;
//--- сбросим значение ошибки
   ResetLastError();
//--- скопируем тиковые объемы для каждого бара
   if(CopyTickVolume(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,volume_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения тикового объема. Код ошибки = %d",GetLastError());
      return;
     }
//--- скопируем время для каждого бара
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,time_buff)==-1)
     {
      PrintFormat("Не удалось скопировать значения времени. Код ошибки = %d",GetLastError());
      return;
     }
//--- получим размер буфера
   size=ArraySize(volume_buff);
//--- откроем файл для записи значений индикатора (если его нет, то создастся автоматически)
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_BIN);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("Файл %s открыт для записи",InpFileName);
      PrintFormat("Путь к файлу: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- сначала запишем размер выборки данных
      uint byteswritten=FileWriteLong(file_handle,(long)size);
      //--- проверка количества записанных данных
      if(byteswritten!=sizeof(long))
        {
         PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
         //--- закрываем файл
         FileClose(file_handle);
         return;
        }
      //--- запишем время и значения объема в файл
      for(int i=0;i<size;i++)
        {
         byteswritten=FileWriteLong(file_handle,(long)time_buff[i]);
         //--- проверка количества записанных данных
         if(byteswritten!=sizeof(long))
           {
            PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
            //--- закрываем файл
            FileClose(file_handle);
            return;
           }
         byteswritten=FileWriteLong(file_handle,volume_buff[i]);
         //--- проверка количества записанных данных
         if(byteswritten!=sizeof(long))
           {
            PrintFormat("Ошибка записи данных. Код ошибки=%d",GetLastError());
            //--- закрываем файл
            FileClose(file_handle);
            return;
           }
        }
      //--- закрываем файл
      FileClose(file_handle);
      PrintFormat("Данные записаны, файл %s закрыт",InpFileName);
     }
   else
      PrintFormat("Не удалось открыть файл %s, Код ошибки = %d",InpFileName,GetLastError());
  }