OBJ_CYCLES

#property strict
//--- описание
#property description "Скрипт строит циклические линии на графике."
#property description "Координаты точек привязки задаются в процентах"
#property description "от размеров окна графика."
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- входные параметры скрипта
input string          InpName="Cycles";   // Имя объекта
input int             InpDate1=10;        // Дата 1-ой точки в %
input int             InpPrice1=45;       // Цена 1-ой точки в %
input int             InpDate2=20;        // Дата 2-ой точки в %
input int             InpPrice2=55;       // Цена 2-ой точки в %
input color           InpColor=clrRed;    // Цвет циклических линий
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // Стиль циклических линий
input int             InpWidth=1;         // Толщина циклических линий
input bool            InpBack=false;      // Объект на заднем плане
input bool            InpSelection=true;  // Выделить для перемещений
input bool            InpHidden=true;     // Скрыт в списке объектов
input long            InpZOrder=0;        // Приоритет на нажатие мышью
//+------------------------------------------------------------------+
//| Создает циклические линии                                        |
//+------------------------------------------------------------------+
bool CyclesCreate(const long            chart_ID=0,        // ID графика
                  const string          name="Cycles",     // имя объекта
                  const int             sub_window=0,      // номер подокна
                  datetime              time1=0,           // время первой точки
                  double                price1=0,          // цена первой точки
                  datetime              time2=0,           // время второй точки
                  double                price2=0,          // цена второй точки
                  const color           clr=clrRed,        // цвет циклических линий
                  const ENUM_LINE_STYLE style=STYLE_SOLID, // стиль циклических линий
                  const int             width=1,           // толщина циклических линий
                  const bool            back=false,        // на заднем плане
                  const bool            selection=true,    // выделить для перемещений
                  const bool            hidden=true,       // скрыт в списке объектов
                  const long            z_order=0)         // приоритет на нажатие мышью
  {
//--- установим координаты точек привязки, если они не заданы
   ChangeCyclesEmptyPoints(time1,price1,time2,price2);
//--- сбросим значение ошибки
   ResetLastError();
//--- создадим циклические линии по заданным координатам
   if(!ObjectCreate(chart_ID,name,OBJ_CYCLES,sub_window,time1,price1,time2,price2))
     {
      Print(__FUNCTION__,
            ": не удалось создать циклические линии! Код ошибки = ",GetLastError());
      return(false);
     }
//--- установим цвет линий
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- установим стиль отображения линий
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- установим толщину линий
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- отобразим на переднем (false) или заднем (true) плане
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- включим (true) или отключим (false) режим перемещения линий мышью
//--- при создании графического объекта функцией ObjectCreate, по умолчанию объект
//--- нельзя выделить и перемещать. Внутри же этого метода параметр selection
//--- по умолчанию равен true, что позволяет выделять и перемещать этот объект
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Перемещает точку привязки                                        |
//+------------------------------------------------------------------+
bool CyclesPointChange(const long   chart_ID=0,    // ID графика
                       const string name="Cycles", // имя объекта
                       const int    point_index=0, // номер точки привязки
                       datetime     time=0,        // координата времени точки привязки
                       double       price=0)       // координата цены точки привязки
  {
//--- если координаты точки не заданы, то перемещаем ее на текущий бар с ценой Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- сбросим значение ошибки
   ResetLastError();
//--- переместим точку привязки
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": не удалось переместить точку привязки! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Удаляет циклические линии                                        |
//+------------------------------------------------------------------+
bool CyclesDelete(const long   chart_ID=0,    // ID графика
                  const string name="Cycles") // имя объекта
  {
//--- сбросим значение ошибки
   ResetLastError();
//--- удалим циклические линии
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": не удалось удалить циклические линии! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Проверяет значения точек привязки циклических линий и для пустых |
//| значений устанавливает значения по умолчанию                     |
//+------------------------------------------------------------------+
void ChangeCyclesEmptyPoints(datetime &time1,double &price1,
                             datetime &time2,double &price2)
  {
//--- если время первой точки не задано, то она будет на текущем баре
   if(!time1)
      time1=TimeCurrent();
//--- если цена первой точки не задана, то она будет иметь значение Bid
   if(!price1)
      price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- если время второй точки не задано, то она лежит на 9 баров левее второй
   if(!time2)
     {
      //--- массив для приема времени открытия 10 последних баров
      datetime temp[10];
      CopyTime(Symbol(),Period(),time1,10,temp);
      //--- установим вторую точку на 9 баров левее первой
      time2=temp[0];
     }
//--- если цена второй точки не задана, то она совпадает с ценой первой точки
   if(!price2)
      price2=price1;
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- проверим входные параметры на корректность
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
     {
      Print("Ошибка! Некорректные значения входных параметров!");
      return;
     }
//--- количество видимых баров в окне графика
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- размер массива price
   int accuracy=1000;
//--- массивы для хранения значений дат и цен, которые будут использованы
//--- для установки и изменения координат точек привязки циклических линий
   datetime date[];
   double   price[];
//--- выделение памяти
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- заполним массив дат
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Не удалось скопировать значения времени! Код ошибки = ",GetLastError());
      return;
     }
//--- заполним массив цен
//--- найдем максимальное и минимальное значение графика
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- определим шаг изменения цены и заполним массив
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- определим точки для рисования циклических линий
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
   int p2=InpPrice2*(accuracy-1)/100;
//--- создадим линию тренда
   if(!CyclesCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],InpColor,
      InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
     {
      return;
     }
//--- перерисуем график и подождем 1 секунду
   ChartRedraw();
   Sleep(1000);
//--- теперь будем перемещать точки привязки
//--- счетчик цикла
   int h_steps=bars/5;
//--- перемещаем вторую точку привязки
   for(int i=0;i<h_steps;i++)
     {
      //--- возьмем следующее значение
      if(d2<bars-1)
         d2+=1;
      //--- сдвигаем точку
      if(!CyclesPointChange(0,InpName,1,date[d2],price[p2]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
      // задержка в 0.05 секунды
      Sleep(50);
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- счетчик цикла
   h_steps=bars/4;
//--- перемещаем первую точку привязки
   for(int i=0;i<h_steps;i++)
     {
      //--- возьмем следующее значение
      if(d1<bars-1)
         d1+=1;
      //--- сдвигаем точку
      if(!CyclesPointChange(0,InpName,0,date[d1],price[p1]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
      // задержка в 0.05 секунды
      Sleep(50);
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- удалим объект с графика
   CyclesDelete(0,InpName);
   ChartRedraw();
//--- задержка в 1 секунду
   Sleep(1000);
//---
  }