OBJ_ELLIPSE

#property strict
//--- описание
#property description "Скрипт строит эллипс на графике."
#property description "Координаты точек привязки задаются"
#property description "в процентах от размеров окна графика."
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- входные параметры скрипта
input string          InpName="Ellipse";         // Имя эллипса
input int             InpDate1=30;               // Дата 1-ой точки в %
input int             InpPrice1=20;              // Цена 1-ой точки в %
input int             InpDate2=70;               // Дата 2-ой точки в %
input int             InpPrice2=80;              // Цена 2-ой точки в %
input double          InpEllipseScale=0.2;       // Соотношение между временной и ценовой шкалами
input color           InpColor=clrRed;           // Цвет эллипса
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Стиль линий эллипса
input int             InpWidth=1;                // Толщина линий эллипса
input bool            InpFill=false;             // Заливка эллипса цветом
input bool            InpBack=false;             // Эллипс на заднем плане
input bool            InpSelection=true;         // Выделить для перемещений
input bool            InpHidden=true;            // Скрыт в списке объектов
input long            InpZOrder=0;               // Приоритет на нажатие мышью
//+------------------------------------------------------------------+
//| Cоздает эллипс по заданным координатам                           |
//+------------------------------------------------------------------+
bool EllipseCreate(const long            chart_ID=0,        // ID графика
                   const string          name="Ellipse",    // имя эллипса
                   const int             sub_window=0,      // номер подокна 
                   datetime              time1=0,           // время первой точки
                   double                price1=0,          // цена первой точки
                   datetime              time2=0,           // время второй точки
                   double                price2=0,          // цена второй точки
                   double                ellipse_scale=0,   // соотношение между временной и ценовой шкалами 
                   const color           clr=clrRed,        // цвет эллипса
                   const ENUM_LINE_STYLE style=STYLE_SOLID, // стиль линий эллипса
                   const int             width=1,           // толщина линий эллипса
                   const bool            fill=false,        // заливка эллипса цветом
                   const bool            back=false,        // на заднем плане
                   const bool            selection=true,    // выделить для перемещений
                   const bool            hidden=true,       // скрыт в списке объектов
                   const long            z_order=0)         // приоритет на нажатие мышью
  {
//--- установим координаты точек привязки, если они не заданы
   ChangeEllipseEmptyPoints(time1,price1,time2,price2);
//--- сбросим значение ошибки
   ResetLastError();
//--- создадим эллипс по заданным координатам
   if(!ObjectCreate(chart_ID,name,OBJ_ELLIPSE,sub_window,time1,price1,time2,price2))
     {
      Print(__FUNCTION__,
            ": не удалось создать эллипс! Код ошибки = ",GetLastError());
      return(false);
     }
//--- установим соотношение между временной и ценовой шкалами 
   ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,InpEllipseScale);
//--- установим цвет эллипса
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- установим стиль линий эллипса
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- установим толщину линий эллипса
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- отобразим на переднем (false) или заднем (true) плане
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- включим (true) или отключим (false) режим выделения эллипса для перемещений
//--- при создании графического объекта функцией ObjectCreate, по умолчанию объект
//--- нельзя выделить и перемещать. Внутри же этого метода параметр selection
//--- по умолчанию равен true, что позволяет выделять и перемещать этот объект
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Перемещает точку привязки эллипса                                |
//+------------------------------------------------------------------+
bool EllipsePointChange(const long   chart_ID=0,     // ID графика
                        const string name="Ellipse", // имя эллипса
                        const int    point_index=0,  // номер точки привязки
                        datetime     time=0,         // координата времени точки привязки
                        double       price=0)        // координата цены точки привязки
  {
//--- если координаты точки не заданы, то перемещаем ее на текущий бар с ценой Bid
   if(!time)
      time=TimeCurrent();
   if(!price)
      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- сбросим значение ошибки
   ResetLastError();
//--- переместим точку привязки
   if(!ObjectMove(chart_ID,name,point_index,time,price))
     {
      Print(__FUNCTION__,
            ": не удалось переместить точку привязки! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Удаляет эллипс                                                   |
//+------------------------------------------------------------------+
bool EllipseDelete(const long   chart_ID=0,     // ID графика
                   const string name="Ellipse") // имя эллипса
  {
//--- сбросим значение ошибки
   ResetLastError();
//--- удалим эллипс
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": не удалось удалить эллипс! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Проверяет значения точек привязки эллипса и для пустых значений  |
//| устанавливает значения по умолчанию                              |
//+------------------------------------------------------------------+
void ChangeEllipseEmptyPoints(datetime &time1,double &price1,
                              datetime &time2,double &price2)
  {
//--- если время первой точки не задано, то она будет на текущем баре
   if(!time1)
      time1=TimeCurrent();
//--- если цена первой точки не задана, то она будет иметь значение Bid
   if(!price1)
      price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- если время второй точки не задано, то она лежит на 9 баров левее второй
   if(!time2)
     {
      //--- массив для приема времени открытия 10 последних баров
      datetime temp[10];
      CopyTime(Symbol(),Period(),time1,10,temp);
      //--- установим вторую точку на 9 баров левее первой
      time2=temp[0];
     }
//--- если цена второй точки не задана, сдвинем ее на 300 пунктов ниже первой
   if(!price2)
      price2=price1-300*SymbolInfoDouble(Symbol(),SYMBOL_POINT);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- проверим входные параметры на корректность
   if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 || 
      InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
     {
      Print("Ошибка! Некорректные значения входных параметров!");
      return;
     }
//--- количество видимых баров в окне графика
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- размер массива price
   int accuracy=1000;
//--- массивы для хранения значений дат и цен, которые будут использованы
//--- для установки и изменения координат точек привязки эллипса
   datetime date[];
   double   price[];
//--- выделение памяти
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- установить порядок данных как в таймсерии
   ArraySetAsSeries(date,true);
   ArraySetAsSeries(price,true);   
//--- заполним массив дат
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Не удалось скопировать значения времени! Код ошибки = ",GetLastError());
      return;
     }
//--- заполним массив цен
//--- найдем максимальное и минимальное значение графика
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- определим шаг изменения цены и заполним массив
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- определим точки для рисования эллипса
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
   int p1=InpPrice1*(accuracy-1)/100;
   int p2=InpPrice2*(accuracy-1)/100;
//--- создадим эллипс
   if(!EllipseCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],InpEllipseScale,
      InpColor,InpStyle,InpWidth,InpFill,InpBack,InpSelection,InpHidden,InpZOrder))
     {
      return;
     }
//--- перерисуем график и подождем 1 секунду
   ChartRedraw();
   Sleep(1000);
//--- теперь будем перемещать точки привязки эллипса
//--- счетчик цикла
   int v_steps=accuracy/5;
//--- перемещаем первую и вторую точки привязки
   for(int i=0;i<v_steps;i++)
     {
      //--- возьмем следующие значения
      if(p1<accuracy-1)
         p1+=1;
      if(p2>1)
         p2-=1;
      //--- сдвигаем точки
      if(!EllipsePointChange(0,InpName,0,date[d1],price[p1]))
         return;
      if(!EllipsePointChange(0,InpName,1,date[d2],price[p2]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     // задержка в 0.01 секунды
      Sleep(10);
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- начальное соотношение между временной и ценовой шкалами
    double ellipse_scale=InpEllipseScale;
//--- счетчик цикла
   v_steps=100;
//--- будем изменять соотношение между временной и ценовой шкалами 
   for(int i=0;i<v_steps;i++)
     {
      ellipse_scale+=2.0/v_steps;
      //--- установим соотношение между временной и ценовой шкалами 
      if (!ObjectSetDouble(0,InpName,OBJPROP_SCALE,ellipse_scale)) return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     // задержка в 0.02 секунды
      Sleep(20);
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- удалим эллипс с графика
   EllipseDelete(0,InpName);
   ChartRedraw();
//--- задержка в 1 секунду
   Sleep(1000);
//---
  }