OBJ_STDDEVCHANNEL

#property strict
//--- описание
#property description "Скрипт строит графический объект \"Канал стандартного отклонения\"."
#property description "Координаты точек привязки задаются в процентах от размеров"
#property description "окна графика."
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- входные параметры скрипта
input string          InpName="StdDevChannel";   // Имя канала
input int             InpDate1=10;               // Дата 1-ой точки в %
input int             InpDate2=40;               // Дата 2-ой точки в %
input double          InpDeviation=1.0;          // Отклонение
input color           InpColor=clrRed;           // Цвет канала
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Стиль линий канала
input int             InpWidth=1;                // Толщина линий канала
input bool            InpFill=false;             // Заливка канала цветом
input bool            InpBack=false;             // Канал на заднем плане
input bool            InpSelection=true;         // Выделить для перемещений
input bool            InpRayRight=false;         // Продолжение канала вправо
input bool            InpHidden=true;            // Скрыт в списке объектов
input long            InpZOrder=0;               // Приоритет на нажатие мышью
//+------------------------------------------------------------------+
//| Создает канал стандартного отклонения по заданным координатам    |
//+------------------------------------------------------------------+
bool StdDevChannelCreate(const long            chart_ID=0,        // ID графика
                         const string          name="Channel",    // имя канала
                         const int             sub_window=0,      // номер подокна 
                         datetime              time1=0,           // время первой точки
                         datetime              time2=0,           // время второй точки
                         const double          deviation=1.0,     // отклонение 
                         const color           clr=clrRed,        // цвет канала
                         const ENUM_LINE_STYLE style=STYLE_SOLID, // стиль линий канала
                         const int             width=1,           // толщина линий канала
                         const bool            fill=false,        // заливка канала цветом
                         const bool            back=false,        // на заднем плане
                         const bool            selection=true,    // выделить для перемещений
                         const bool            ray_right=false,   // продолжение канала вправо
                         const bool            hidden=true,       // скрыт в списке объектов
                         const long            z_order=0)         // приоритет на нажатие мышью
  {
//--- установим координаты точек привязки, если они не заданы
   ChangeChannelEmptyPoints(time1,time2);
//--- сбросим значение ошибки
   ResetLastError();
//--- создадим канал по заданным координатам
   if(!ObjectCreate(chart_ID,name,OBJ_STDDEVCHANNEL,sub_window,time1,0,time2,0))
     {
      Print(__FUNCTION__,
            ": не удалось создать канал стандартного отклонения! Код ошибки = ",GetLastError());
      return(false);
     }
//--- установим величину отклонения, от нее зависит ширина канала
   ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation);
//--- установим цвет канала
   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- установим стиль линий канала
   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- установим толщину линий канала
   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- отобразим на переднем (false) или заднем (true) плане
   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- включим (true) или отключим (false) режим выделения канала для перемещений
//--- при создании графического объекта функцией ObjectCreate, по умолчанию объект
//--- нельзя выделить и перемещать. Внутри же этого метода параметр selection
//--- по умолчанию равен true, что позволяет выделять и перемещать этот объект
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- включим (true) или отключим (false) режим продолжения отображения канала вправо
   ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- установим приоритет на получение события нажатия мыши на графике
   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Перемещает точку привязки канала                                 |
//+------------------------------------------------------------------+
bool StdDevChannelPointChange(const long   chart_ID=0,     // ID графика
                              const string name="Channel", // имя канала
                              const int    point_index=0,  // номер точки привязки
                              datetime     time=0)         // координата времени точки привязки
  {
//--- если время точки не задано, то перемещаем ее на текущий бар
   if(!time)
      time=TimeCurrent();
//--- сбросим значение ошибки
   ResetLastError();
//--- переместим точку привязки
   if(!ObjectMove(chart_ID,name,point_index,time,0))
     {
      Print(__FUNCTION__,
            ": не удалось переместить точку привязки! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Изменяет отклонение канала                                       |
//+------------------------------------------------------------------+
bool StdDevChannelDeviationChange(const long   chart_ID=0,     // ID графика
                                  const string name="Channel", // имя канала
                                  const double deviation=1.0)  // отклонение
  {
//--- сбросим значение ошибки
   ResetLastError();
//--- изменим угол наклона линии тренда
   if(!ObjectSetDouble(chart_ID,name,OBJPROP_DEVIATION,deviation))
     {
      Print(__FUNCTION__,
            ": не удалось изменить отклонение канала! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Удаляет канал                                                    |
//+------------------------------------------------------------------+
bool StdDevChannelDelete(const long   chart_ID=0,     // ID графика
                         const string name="Channel") // имя канала
  {
//--- сбросим значение ошибки
   ResetLastError();
//--- удалим канал
   if(!ObjectDelete(chart_ID,name))
     {
      Print(__FUNCTION__,
            ": не удалось удалить канал! Код ошибки = ",GetLastError());
      return(false);
     }
//--- успешное выполнение
   return(true);
  }
//+------------------------------------------------------------------+
//| Проверяет значения точек привязки канала и для пустых значений   |
//| устанавливает значения по умолчанию                              |
//+------------------------------------------------------------------+
void ChangeChannelEmptyPoints(datetime &time1,datetime &time2)
  {
//--- если время второй точки не задано, то она будет на текущем баре
   if(!time2)
      time2=TimeCurrent();
//--- если время первой точки не задано, то она лежит на 9 баров левее второй
   if(!time1)
     {
      //--- массив для приема времени открытия 10 последних баров
      datetime temp[10];
      CopyTime(Symbol(),Period(),time2,10,temp);
      //--- установим вторую точку на 9 баров левее второй
      time1=temp[0];
     }
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- проверим входные параметры на корректность
   if(InpDate1<0 || InpDate1>100 || 
      InpDate2<0 || InpDate2>100)
     {
      Print("Ошибка! Некорректные значения входных параметров!");
      return;
     }
//--- количество видимых баров в окне графика
   int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- размер массива price
   int accuracy=1000;
//--- массивы для хранения значений дат и цен, которые будут использованы
//--- для установки и изменения координат точек привязки канала
   datetime date[];
   double   price[];
//--- выделение памяти
   ArrayResize(date,bars);
   ArrayResize(price,accuracy);
//--- заполним массив дат
   ResetLastError();
   if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
     {
      Print("Не удалось скопировать значения времени! Код ошибки = ",GetLastError());
      return;
     }
//--- заполним массив цен
//--- найдем максимальное и минимальное значение графика
   double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
   double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- определим шаг изменения цены и заполним массив
   double step=(max_price-min_price)/accuracy;
   for(int i=0;i<accuracy;i++)
      price[i]=min_price+i*step;
//--- определим точки для рисования канала
   int d1=InpDate1*(bars-1)/100;
   int d2=InpDate2*(bars-1)/100;
//--- создадим канал стандартного отклонения
   if(!StdDevChannelCreate(0,InpName,0,date[d1],date[d2],InpDeviation,InpColor,InpStyle,
      InpWidth,InpFill,InpBack,InpSelection,InpRayRight,InpHidden,InpZOrder))
     {
      return;
     }
//--- перерисуем график и подождем 1 секунду
   ChartRedraw();
   Sleep(1000);
//--- теперь будем перемещать канал по горизонтали вправо и расширять его
//--- счетчик цикла
   int h_steps=bars/2;
//--- перемещаем канал
   for(int i=0;i<h_steps;i++)
     {
      //--- возьмем следующие значения
      if(d1<bars-1)
         d1+=1;
      if(d2<bars-1)
         d2+=1;
      //--- переместим точки привязки
      if(!StdDevChannelPointChange(0,InpName,0,date[d1]))
         return;
      if(!StdDevChannelPointChange(0,InpName,1,date[d2]))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
      // задержка в 0.05 секунды
      Sleep(50);
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- счетчик цикла
   double v_steps=InpDeviation*2;
//--- расширим канал
   for(double i=InpDeviation;i<v_steps;i+=10.0/accuracy)
     {
      if(!StdDevChannelDeviationChange(0,InpName,i))
         return;
      //--- проверим факт принудительного завершения скрипта
      if(IsStopped())
         return;
      //--- перерисуем график
      ChartRedraw();
     }
//--- задержка в 1 секунду
   Sleep(1000);
//--- удалим канал с графика
   StdDevChannelDelete(0,InpName);
   ChartRedraw();
//--- задержка в 1 секунду
   Sleep(1000);
//---
  }