#property strict
//--- описание
#property description "Скрипт строит графический объект \"Веер Ганна\"."
#property description "Координаты точек привязки задаются в процентах от"
#property description "размеров окна графика."
//--- покажем окно входных параметров при запуске скрипта
#property script_show_inputs
//--- входные параметры скрипта
input string InpName="GannFan"; // Имя веера
input int InpDate1=15; // Дата 1-ой точки в %
input int InpPrice1=25; // Цена 1-ой точки в %
input int InpDate2=85; // Дата 2-ой точки в %
input double InpScale=2.0; // Масштаб
input bool InpDirection=false; // Направление тренда
input color InpColor=clrRed; // Цвет веера
input ENUM_LINE_STYLE InpStyle=STYLE_DASHDOTDOT; // Стиль линий веера
input int InpWidth=1; // Толщина линий веера
input bool InpBack=false; // Веер на заднем плане
input bool InpSelection=true; // Выделить для перемещений
input bool InpHidden=true; // Скрыт в списке объектов
input long InpZOrder=0; // Приоритет на нажатие мышью
//+------------------------------------------------------------------+
//| Создает "Веер Ганна" |
//+------------------------------------------------------------------+
bool GannFanCreate(const long chart_ID=0, // ID графика
const string name="GannFan", // имя веера
const int sub_window=0, // номер подокна
datetime time1=0, // время первой точки
double price1=0, // цена первой точки
datetime time2=0, // время второй точки
const double scale=1.0, // масштаб
const bool direction=true, // направление тренда
const color clr=clrRed, // цвет веера
const ENUM_LINE_STYLE style=STYLE_SOLID, // стиль линий веера
const int width=1, // толщина линий веера
const bool back=false, // на заднем плане
const bool selection=true, // выделить для перемещений
const bool hidden=true, // скрыт в списке объектов
const long z_order=0) // приоритет на нажатие мышью
{
//--- установим координаты точек привязки, если они не заданы
ChangeGannFanEmptyPoints(time1,price1,time2);
//--- сбросим значение ошибки
ResetLastError();
//--- создадим "Веер Ганна" по заданным координатам
if(!ObjectCreate(chart_ID,name,OBJ_GANNFAN,sub_window,time1,price1,time2,0))
{
Print(__FUNCTION__,
": не удалось создать \"Веер Ганна\"! Код ошибки = ",GetLastError());
return(false);
}
//--- изменим масштаб (количество пипсов на бар)
ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale);
//--- изменим направление тренда "Веера Ганна" (true - нисходящий, false - восходящий)
ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction);
//--- установим цвет веера
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- установим стиль отображения линий веера
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- установим толщину линий веера
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- отобразим на переднем (false) или заднем (true) плане
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- включим (true) или отключим (false) режим выделения веера для перемещений
//--- при создании графического объекта функцией ObjectCreate, по умолчанию объект
//--- нельзя выделить и перемещать. Внутри же этого метода параметр selection
//--- по умолчанию равен true, что позволяет выделять и перемещать этот объект
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- скроем (true) или отобразим (false) имя графического объекта в списке объектов
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- установим приоритет на получение события нажатия мыши на графике
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- успешное выполнение
return(true);
}
//+------------------------------------------------------------------+
//| Перемещает точку привязки "Веера Ганна" |
//+------------------------------------------------------------------+
bool GannFanPointChange(const long chart_ID=0, // ID графика
const string name="GannFan", // имя веера
const int point_index=0, // номер точки привязки
datetime time=0, // координата времени точки привязки
double price=0) // координата цены точки привязки
{
//--- если координаты точки не заданы, то перемещаем ее на текущий бар с ценой Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- сбросим значение ошибки
ResetLastError();
//--- переместим точку привязки веера
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
": не удалось переместить точку привязки! Код ошибки = ",GetLastError());
return(false);
}
//--- успешное выполнение
return(true);
}
//+------------------------------------------------------------------+
//| Изменяет масштаб "Веера Ганна" |
//+------------------------------------------------------------------+
bool GannFanScaleChange(const long chart_ID=0, // ID графика
const string name="GannFan", // имя веера
const double scale=1.0) // масштаб
{
//--- сбросим значение ошибки
ResetLastError();
//--- изменим масштаб (количество пипсов на бар)
if(!ObjectSetDouble(chart_ID,name,OBJPROP_SCALE,scale))
{
Print(__FUNCTION__,
": не удалось изменить масштаб! Код ошибки = ",GetLastError());
return(false);
}
//--- успешное выполнение
return(true);
}
//+------------------------------------------------------------------+
//| Изменяет направление тренда "Веера Ганна" |
//+------------------------------------------------------------------+
bool GannFanDirectionChange(const long chart_ID=0, // ID графика
const string name="GannFan", // имя веера
const bool direction=true) // направление тренда
{
//--- сбросим значение ошибки
ResetLastError();
//--- изменим направление тренда "Веера Ганна"
if(!ObjectSetInteger(chart_ID,name,OBJPROP_DIRECTION,direction))
{
Print(__FUNCTION__,
": не удалось изменить направление тренда! Код ошибки = ",GetLastError());
return(false);
}
//--- успешное выполнение
return(true);
}
//+------------------------------------------------------------------+
//| Функция удаляет "Веер Ганна" с графика |
//+------------------------------------------------------------------+
bool GannFanDelete(const long chart_ID=0, // ID графика
const string name="GannFan") // имя веера
{
//--- сбросим значение ошибки
ResetLastError();
//--- удалим веер Ганна
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": не удалось удалить \"Веер Ганна\"! Код ошибки = ",GetLastError());
return(false);
}
//--- успешное выполнение
return(true);
}
//+------------------------------------------------------------------+
//| Проверяет значения точек привязки "Веера Ганна" и для пустых |
//| значений устанавливает значения по умолчанию |
//+------------------------------------------------------------------+
void ChangeGannFanEmptyPoints(datetime &time1,double &price1,datetime &time2)
{
//--- если время второй точки не задано, то она будет на текущем баре
if(!time2)
time2=TimeCurrent();
//--- если время первой точки не задано, то она лежит на 9 баров левее второй
if(!time1)
{
//--- массив для приема времени открытия 10 последних баров
datetime temp[10];
CopyTime(Symbol(),Period(),time2,10,temp);
//--- установим первую точку на 9 баров левее второй
time1=temp[0];
}
//--- если цена первой точки не задана, то она будет иметь значение Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- проверим входные параметры на корректность
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100)
{
Print("Ошибка! Некорректные значения входных параметров!");
return;
}
//--- количество видимых баров в окне графика
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- размер массива price
int accuracy=1000;
//--- массивы для хранения значений дат и цен, которые будут использованы
//--- для установки и изменения координат точек привязки веера
datetime date[];
double price[];
//--- выделение памяти
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- заполним массив дат
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Не удалось скопировать значения времени! Код ошибки = ",GetLastError());
return;
}
//--- заполним массив цен
//--- найдем максимальное и минимальное значение графика
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- определим шаг изменения цены и заполним массив
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- определим точки для рисования веера Ганна
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- создадим веер Ганна
if(!GannFanCreate(0,InpName,0,date[d1],price[p1],date[d2],InpScale,InpDirection,
InpColor,InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- перерисуем график и подождем 1 секунду
ChartRedraw();
Sleep(1000);
//--- теперь будем перемещать точку привязки веера
//--- счетчик цикла
int v_steps=accuracy/2;
//--- перемещаем первую точку привязки по вертикали
for(int i=0;i<v_steps;i++)
{
//--- возьмем следующее значение
if(p1<accuracy-1)
p1+=1;
//--- сдвигаем точку
if(!GannFanPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- проверим факт принудительного завершения скрипта
if(IsStopped())
return;
//--- перерисуем график
ChartRedraw();
}
//--- задержка в 1 секунду
Sleep(1000);
//--- изменим направление тренда веера на нисходящее
GannFanDirectionChange(0,InpName,true);
//--- перерисуем график
ChartRedraw();
//--- задержка в 1 секунду
Sleep(1000);
//--- удалим веер с графика
GannFanDelete(0,InpName);
ChartRedraw();
//--- задержка в 1 секунду
Sleep(1000);
//---
} |
Константы, перечисления и структуры 
